------------------------------------------------------------------------------
--                                                                          --
--                            Matreshka Project                             --
--                                                                          --
--         Localization, Internationalization, Globalization for Ada        --
--                                                                          --
--                        Runtime Library Component                         --
--                                                                          --
------------------------------------------------------------------------------
--                                                                          --
-- Copyright © 2011, Vadim Godunko <vgodunko@gmail.com>                     --
-- All rights reserved.                                                     --
--                                                                          --
-- Redistribution and use in source and binary forms, with or without       --
-- modification, are permitted provided that the following conditions       --
-- are met:                                                                 --
--                                                                          --
--  * Redistributions of source code must retain the above copyright        --
--    notice, this list of conditions and the following disclaimer.         --
--                                                                          --
--  * Redistributions in binary form must reproduce the above copyright     --
--    notice, this list of conditions and the following disclaimer in the   --
--    documentation and/or other materials provided with the distribution.  --
--                                                                          --
--  * Neither the name of the Vadim Godunko, IE nor the names of its        --
--    contributors may be used to endorse or promote products derived from  --
--    this software without specific prior written permission.              --
--                                                                          --
-- THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS      --
-- "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT        --
-- LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR    --
-- A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT     --
-- HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,   --
-- SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED --
-- TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR   --
-- PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF   --
-- LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING     --
-- NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS       --
-- SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.             --
--                                                                          --
------------------------------------------------------------------------------
--  $Revision: 1793 $ $Date: 2011-06-11 11:40:44 +0400 (Sat, 11 Jun 2011) $
------------------------------------------------------------------------------

package body League.Holders.Generic_Floats is

   -----------------
   -- Constructor --
   -----------------

   overriding function Constructor
    (Is_Empty : not null access Boolean) return Float_Container
   is
      pragma Assert (Is_Empty.all);

   begin
      return
       (Counter  => <>,
        Is_Empty => Is_Empty.all,
        Value    => <>);
   end Constructor;

   -------------
   -- Element --
   -------------

   function Element (Self : Holder) return Num is
   begin
      if Self.Data.all not in Float_Container
        and Self.Data.all not in Universal_Float_Container
      then
         raise Constraint_Error with "invalid type of value";
      end if;

      if Self.Data.Is_Empty then
         raise Constraint_Error with "value is empty";
      end if;

      if Self.Data.all in Universal_Float_Container then
         return Num (Universal_Float_Container'Class (Self.Data.all).Value);

      else
         return Float_Container'Class (Self.Data.all).Value;
      end if;
   end Element;

   -----------
   -- First --
   -----------

   overriding function First
    (Self : not null access constant Float_Container) return Universal_Float
   is
      pragma Unreferenced (Self);

   begin
      return Universal_Float (Num'First);
   end First;

   ---------
   -- Get --
   ---------

   overriding function Get
    (Self : not null access constant Float_Container)
       return Universal_Float is
   begin
      return Universal_Float (Self.Value);
   end Get;

   ----------
   -- Last --
   ----------

   overriding function Last
    (Self : not null access constant Float_Container) return Universal_Float
   is
      pragma Unreferenced (Self);

   begin
      return Universal_Float (Num'Last);
   end Last;

   ---------------------
   -- Replace_Element --
   ---------------------

   procedure Replace_Element (Self : in out Holder; To : Num) is
   begin
      if Self.Data.all not in Float_Container
        and Self.Data.all not in Universal_Float_Container
      then
         raise Constraint_Error with "invalid type of value";
      end if;

      --  XXX This subprogram can be improved to reuse shared segment when
      --  possible.

      if Self.Data.all in Universal_Float_Container then
         Dereference (Self.Data);
         Self.Data :=
           new Universal_Float_Container'
                (Counter  => <>,
                 Is_Empty => False,
                 Value    => Universal_Float (To));

      else
         Dereference (Self.Data);
         Self.Data :=
           new Float_Container'
                (Counter => <>, Is_Empty => False, Value => To);
      end if;
   end Replace_Element;

   ---------
   -- Set --
   ---------

   overriding procedure Set
    (Self : not null access Float_Container; To : Universal_Float) is
   begin
      Self.Is_Empty := False;
      Self.Value    := Num (To);
   end Set;

   ---------------
   -- To_Holder --
   ---------------

   function To_Holder (Item : Num) return Holder is
   begin
      return
       (Ada.Finalization.Controlled with
          new Float_Container'
               (Counter => <>, Is_Empty => False, Value => Item));
   end To_Holder;

end League.Holders.Generic_Floats;
