------------------------------------------------------------------------------
--                                                                          --
--                An Ada2005 binding to the Qt C++ framework                --
--                                                                          --
------------------------------------------------------------------------------
--                                                                          --
-- Copyright © 2008, 2009 Vadim Godunko <vgodunko@gmail.com>                --
--                                                                          --
-- QtAda is free software;  you can  redistribute it and/or modify it under --
-- terms of the  GNU General Public License as published  by the Free Soft- --
-- ware  Foundation;  either version 2,  or (at your option) any later ver- --
-- sion. QtAda is distributed in the hope that it will be useful, but WITH- --
-- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
-- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
-- for  more details.  You should have  received  a copy of the GNU General --
-- Public License distributed with QtAda;  see file COPYING.  If not, write --
-- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
-- Boston, MA 02110-1301, USA.                                              --
--                                                                          --
-- As a special exception,  if other files  instantiate  generics from this --
-- unit, or you link  this unit with other files  to produce an executable, --
-- this  unit  does not  by itself cause  the resulting  executable  to  be --
-- covered  by the  GNU  General  Public  License.  This exception does not --
-- however invalidate  any other reasons why  the executable file  might be --
-- covered by the  GNU Public License.                                      --
--                                                                          --
------------------------------------------------------------------------------
--  $Revision: 3752 $ $Date: 2010-10-08 17:08:29 +0400 (Fri, 08 Oct 2010) $
------------------------------------------------------------------------------
with System.Address_To_Access_Conversions;

package Qt_Ada.Internals.Objects is

   pragma Preelaborate;

   type QObject is null record;
   pragma Convention (C, QObject);
   --  This is representation of the all C++ objects of the QObject subclasses
   --  casted to QObject.

   package Conversions is new System.Address_To_Access_Conversions (QObject);

   subtype QObject_Access is Conversions.Object_Pointer;

   type Q_Object_Base is limited interface;
   --  Base interface for all Ada objects of types derived from Q_Object. This
   --  interface required for multiple inheritance simulation. It has only one
   --  dispatching operation, which returns pointer to the associated C++
   --  object which supports QObject operations.

   type Q_Object_Base_Access is access all Q_Object_Base'Class;
   pragma Convention (C, Q_Object_Base_Access);

   not overriding
   function QObject_View (Self : not null access constant Q_Object_Base)
     return not null access QObject
       is abstract;
   --  Returns view to the associated C++ object which casted to QObject.

   type Q_Object_Impl_Base is abstract limited new Q_Object_Base with private;

   not overriding procedure Finalize
    (Self : not null access Q_Object_Impl_Base) is null;

   overriding
   function QObject_View (Self : not null access constant Q_Object_Impl_Base)
     return not null access QObject;

   procedure Initialize
    (Self   : not null access Q_Object_Impl_Base'Class;
     Object : not null QObject_Access);

private

   type Q_Object_Impl_Base is abstract limited new Q_Object_Base with record
      Object : QObject_Access;
   end record;

   type Q_Object_Impl_Base_Access is access all Q_Object_Impl_Base'Class;

end Qt_Ada.Internals.Objects;
