--Copyright The Numerical Algorithms Group Limited 1991.
-------------------------------- lode.input ---------------------------
 
)cl all
-- this will be the unknown
y := operator y
 
-- homogeneous equation with constant coefficients
deq := differentiate(y x, x, 2) + differentiate(y x, x) + y x
solve(deq, y, x).basis
 
-- initial value problem: y'' + y = 0, y(0) = y'(0) = 1
deq := differentiate(y x, x, 2) + y x
solve(deq, y, x = 0, [1, 1])
 
-- same with a non-constant right-hand side
solve(deq = sin x, y, x)
 
-- some inhomogenuous equations with rational coefficients
deq := x**3 * differentiate(y x, x, 3) + x**2 * differentiate(y x, x, 2) - _
2 * x * differentiate(y x, x) + 2 * y x = 2 * x**4
solve(deq, y, x)
-- same with initial conditions
solve(deq, y, x = 1, [b, 0, a])
 
-- third order equation with nontrivial singularities
deq := (x**9 + x**3) * differentiate(y x, x, 3) + _
18 * x**8 * differentiate(y x, x,2) - 90 * x * differentiate(y x, x) - _
30 * (11*x**6-3) * y x
solve(deq, y, x).basis
 
-- third order equation on a curve of genus 0
deq := (2*x+2)* differentiate(y x, x, 3) + 3* differentiate(y x, x, 2) + _
(2*x**2+2*x)* differentiate(y x,x) - sqrt(x+1) * y x = 2 * x**2 + x - 1
solve(deq, y, x).particular
 
-- this equation is irreducible over the rational functions
deq := 2*x**3*differentiate(y x,x,2) + 3*x**2*differentiate(y x,x) - 2*y x
solve(deq,y,x).basis
 
 
 


