## Tcl8.6.0/Tk8.6.0 Documentation > Tcl Commands, version 8.6.0 > tailcall

### Tcl/Tk Applications | Tcl Commands | Tk Commands | [incr Tcl] Package Commands | SQLite Package Commands | TDBC Package Commands | tdbc::mysql Package Commands | tdbc::odbc Package Commands | tdbc::postgres Package Commands | tdbc::sqlite3 Package Commands | Thread Package Commands | Tcl C API | Tk C API | [incr Tcl] Package C API | TDBC Package C API

### NAME

tailcall — Replace the current procedure with another command

### SYNOPSIS

tailcall command ?arg ...?

### DESCRIPTION

The tailcall command replaces the currently executing procedure, lambda application, or method with another command. The command, which will have arg ... passed as arguments if they are supplied, will be looked up in the current namespace context, not in the caller's. Apart from that difference in resolution, it is equivalent to:

    return [uplevel 1 [list command ?arg ...?]]

This command may not be invoked from within an uplevel into a procedure or inside a catch inside a procedure or lambda.

### EXAMPLE

Compute the factorial of a number.

    proc factorial {n {accum 1}} {
        if {$n < 2} {
            return $accum
        }
        tailcall factorial [expr {$n - 1}] [expr {$accum * $n}]
    }

Print the elements of a list with alternating lines having different indentations.

    proc printList {theList} {
        if {[llength $theList]} {
            puts "> [lindex $theList 0]"
            tailcall printList2 [lrange $theList 1 end]
        }
    }
    proc printList2 {theList} {
        if {[llength $theList]} {
            puts "< [lindex $theList 0]"
            tailcall printList [lrange $theList 1 end]
        }
    }

### SEE ALSO

apply, proc, uplevel

### KEYWORDS

call, recursion, tail recursion
Copyright © 1993 The Regents of the University of California. Copyright © 1994-1996 Sun Microsystems, Inc.