Tivoli Service Desk 6.0 Developer's Toolkit - Guide du concepteur d'interface (Interface Designer)

Chapitre 4 : Références des commandes EHLLAPI

Retour à la table des matières


EMUClrTypeIn

Description

Cette commande, lorsqu'elle exécutée à l'emplacement du curseur, efface le contenu de la zone et y entre la chaîne de caractères appropriée, en la tronquant éventuellement suivant la longueur limite définie.

Paramètres

conn : EMUCONNECTION 
str : STRING EXPRESSION
length: INTEGER EXPRESSION

Remarques concernant les paramètres

Paramètre Description
conn La connexion doit être initialisée avec EMUConnect.
str Chaîne de caractères à insérer dans la zone sélectionnée.
length Paramètre facultatif. La longueur maximale de la zone destinée à recevoir la chaîne de caractères peut être tronquée afin d'adopter la taille requise.

Type de données renvoyées

INTEGER

Remarques

La chaîne de caractères est saisie à partir du point point d'emplacement du curseur. La position finale du curseur se situe après le dernier caractère de la chaîne, exactement comme si un utilisateur avait saisi la chaîne au clavier. Cette fonction permet de réaliser une tâche qui équivaut à appeler EMUPressKey avec $EMUClear, puis EMUTypeIn.

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
   str :STRING; 
    ACTIONS 
   rc := EMUConnect(conn, 'A');
    -- "conn" est désormais associé à la session A 
            IF (rc < 1) THEN 
    -- erreur de traitement 
   ELSE 
     str := 'HELLO WORLD!'; 
     rc := EMUClrTypeIn(conn,str); 
            IF (rc < 1) THEN 
    -- erreur de traitement 
END; 
   EMUDisConnect(conn); -- ressources libérées pour "conn".
END; 
END; 

Voir aussi :

EMUTypeIn

EMUConnect

Description

Initialise une connexion EHLLAPI, en activant la session de terminal définie par sessName.

Paramètres

conn : EMUCONNECTION 
sessName: STRING EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Ce descripteur est initialisé au moyen de différents paramètres de terminal. Ne transférez pas le descripteur à EMUConnect plus d'une fois par application, sauf si vous souhaitez effacer l'initialisation du descripteur précédent.
sessName Nom abrégé de la session de terminal de Communications Manager (ce nom est généralement 'A,' 'B,' 'C,' dans le cas des sessions de terminal 3270). Cette session de terminal doit être lancée dans Communications Manager avant l'appel de EMUConnect.

Type de données renvoyées

INTEGER

Remarques

Cette commande doit être exécutée avant de transférer le descripteur de la connexion vers une autre commande EHLLAPI.

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
   str :STRING; 
    ACTIONS 
   rc := EMUConnect(conn, 'A');
    -- "conn" est désormais associé à la session A
            IF (rc < 1) THEN 
    -- erreur de traitement 
   ELSE 
     str := 'HELLO WORLD!'; 
     rc := EMUClrTypeIn(conn,str); 
            IF (rc < 1) THEN 
    -- erreur de traitement 
END; 
   EMUDisConnect(conn); -- ressources libérées pour "conn". 
END; 
END; 

Voir aussi :

EMUDisConnnect

EMUDisConnect

Description

Désactive la session d'émulation connectée, en libérant les ressources allouées au descripteur de la connexion.

Paramètres

conn : EMUCONNECTION 

Remarques concernant les paramètres

Paramètre Description
conn Descripteur de connexion à libérer.

Type de données renvoyées

INTEGER

Remarques

Le descripteur de connexion est $Unknown après l'exécution de cette commande. Pour réinitialiser le descripteur de connexion, appelez la fonction EMUConnect.

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
   str :STRING; 
    ACTIONS 
   rc := EMUConnect(conn, 'A');
    -- "conn" est désormais associé à la session A
            IF (rc < 1) THEN 
    -- erreur de traitement 
   ELSE 
     str := 'HELLO WORLD!'; 
     rc := EMUClrTypeIn(conn,str); 
            IF (rc < 1) THEN 
    -- erreur de traitement 
END; 
   EMUDisConnect(conn); -- ressources libérées pour "conn". 
END; 
END;

Voir aussi :

EMUConnect

EMUFillBuffer

Description

Lit une chaîne de caractères dans une session de terminal, en un point donné, en tenant compte de la longueur spécifiée.

Paramètres

conn : EMUCONNECTION 
row : INTEGER EXPRESSION 
col : INTEGER EXPRESSION 
length: INTEGER EXPRESSION 
inStr : STRING PARAMETER 

Remarques concernant les paramètres

Paramètre Description
conn Descripteur de connexion désignant la session utilisée par l'interpréteur de TSD Script pour rechercher la chaîne de caractères.
row Ligne de l'écran du terminal. Ce nombre est généralement compris entre 1 et 24. La ligne 1 correspond à la ligne située en haut de l'écran.
col Colonne d'où sont extraits les caractères. Les colonnes pertinentes sont habituellement numérotées de 1 à 80. La colonne 1 d'un écran de texte correspond à celle qui est située à l'extrême gauche.
length Nombre de caractères à copier sur l'écran.
inStr Chaîne de caractères dans laquelle les données sont copiées.

Type de données renvoyées

INTEGER

Remarques

L'emplacement du curseur hôte n'est pas pertinent pour cette commande. Le curseur ne subit aucun déplacement. L'interpréteur de TSD Script peut exécuter la commande même lorsque la session est "active" (ZIO signalant le verrouillage d'entrée système).

Exemple

VARIABLES
            rc :INTEGER; 
   str :STRING; 
conn:EMUCONNECTION; 
    ACTIONS 
   rc := EMUConnect(conn, 'A'); 
            IF (rc < 1) THEN 
    -- erreur de traitement
   ELSE 
      rc := EMUFillBuffer(conn,1,1,20,str); 
            IF (rc < 1) THEN 
    -- erreur de traitement 
   ELSE 
         WinMessageBox($DESKTOP,'FillBuff',$MBOK,
                       'Row 1, Col 1 '& 
                       'first 20 chars is:'& str); 
END; 
      EMUDisconnect(conn);
END; 
END; 

Voir aussi :

EMUMapDownload

EMUInFile

Description

Lance la lecture d'un fichier texte dans l'écran hôte en commençant au point de positionnement du curseur. A la fin de chaque fichier texte, le code de touche spécifié est enclenché.

Paramètres

conn : EMUCONNECTION 
filename: STRING EXPRESSION
keycode: INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Indique une session connectée qui est la cible du fichier d'entrée.
filename Nom du fichier texte dont la lecture doit être lancée dans l'écran hôte.
keycode L'un des codes de touche reconnus par l'interface EHLLAPI.

Cette saisie est effectuée après la lecture de chaque ligne du fichier dans l'écran.

Type de données renvoyées

INTEGER

Exemple

VARIABLES
            rc :INTEGER; 
    ACTIONS 
   rc := EMUConnect(conn, 'A'); 
            IF (rc < 1) THEN 
    -- erreur de traitement
   ELSE 
      rc := EMUInFile(conn,'EXAMPLE.TXT', $EMUTab); 
            IF (rc < 1) THEN 
    -- erreur de traitement 
END; 
      EMUDisconnect(conn);
END; 
END; 

Suppose que le fichier EXAMPLE.TXT contient le texte suivant :

Voici une description.
Voici une autre ligne de description.
Enfin, voici la troisième ligne de description. 

Si l'aspect de l'écran est le suivant :

BLGRRR====================================
In===>______________________________________________ 12/12/93 
Début : __________________  Fin : ______________________
Description: _________________________________________ 
______________________________________________________ 
______________________________________________________ 
______________________________________________________ 
______________________________________________________ 
========================================

Suppose que le curseur est positionné au début de la description.
Lorsque cet échantillon de code est exécuté, le résultat affiché est le suivant :

BLGRRR====================================
In===>______________________________________________ 12/12/93 
Début : __________________ Fin : _____________________
Description : Voici une description.
Voici une autre ligne de description.
Enfin, voici la troisième ligne de description.
______________________________________________________ 
______________________________________________________ 

======================================== 

Voir aussi :

EMUOutFile

EMUMapDownload

Description

Télécharge un écran de données vers l'aval, comme spécifié dans la mappe correspondante.

Paramètres

conn : EMUCONNECTION 
mapName   : STRING EXPRESSION 
downloadBuff: ANY 

Remarques concernant les paramètres

Paramètre Description
conn Indique la session depuis laquelle les données doivent être téléchargées vers l'aval.
mapName Nom du fichier de mappe à utiliser pour le téléchargement vers l'aval.
downloadBuff Structure d'enregistrement contenant (au minimum) les zones nommées dans le fichier de mappe. La lecture des données s'effectue depuis le point spécifié dans la mappe, les données étant ensuite placées dans la zone d'enregistrement dont le nom est identique à celui qui est mentionné dans le fichier de mappe.

Type de données renvoyées

INTEGER

Remarques

EMUMapDownload remplace l'usage de nombreuses commandes EMUFillBuffer, car les mappes permettent de convertir rapidement les types de données en types TSD Script. Si par exemple, vous utilisez EMUFillBuffer pour extraire certaines données d'un écran, toutes les données obtenues constituent une chaîne de caractères TSD Script. Vous devez ensuite convertir les données en procédant zone par zone.

Dans le cas des types de données TIME, DATE, INTEGER et REAL, la commande EMUMapDownload permet d'éliminer les espaces de début et de fin présents dans les zones de données, avant que des valeurs ne soient introduites dans les zones d'enregistrement. Dans le cas de types STRING, les données sont copiées telles quelles depuis l'écran hôte vers la zone d'enregistrement (action similaire à EMUFillBuffer).

Exemple

TYPES
   SomeRec IS RECORD 
      Name:STRING; 
      Age :INTEGER; 
END; 
VARIABLES
            rc :INTEGER; 
   rec :SomeRec; 
conn:EMUCONNECTION; 
    ACTIONS 
   rc := EMUConnect(conn, 'A'); 
            IF (rc < 1) THEN 
    -- erreur de traitement
   ELSE 
      rc := EMUMapDownload(conn,'EX1.MAP',rec); 
            IF (rc < 1) THEN 
    -- erreur de traitement 
   ELSE 
         -- traitement immédiat des données contenues dans rec.
END; 
      EMUDisconnect(conn);
END; 
END; 

Supposons que le contenu du fichier EX1.MAP est :

*FIELDS 
NAME 5 12 10 SYSFORMAT DEFAULT_FORMAT 
AGE 6 6 3 SYSFORMAT DEFAULT_FORMAT 

Supposons que l'écran d'hôte est semblable à :

========================================
NOM COMPLET : Stéphane Durand
AGE : 18

========================================

Compte tenu des conditions de l'exemple, après l'exécution de EMUMapDownload, la variable rec contient le nom de Stéphane Durand et l'âge 18.

Voir aussi :

EMUMapUpload

Description

Télécharge un écran de données complet vers l'amont, comme spécifié dans le fichier de mappe correspondant.

Paramètres

conn : EMUCONNECTION 
mapName   : STRING EXPRESSION 
uploadBuff: ANY 

Remarques concernant les paramètres

Paramètre Description
conn Précise la session vers laquelle les données doivent être téléchargées en amont.
mapName Indique le nom du fichier de mappe qui détermine l'emplacement et la conversion des données lors d'un téléchargement vers l'amont.
uploadBuff Variable contenant les données à télécharger en amont vers l'écran. Le type de cette variable peut être soit un type TSD Script simple (TIME, DATE, INTEGER, STRING), soit un type d'enregistrement défini par l'utilisateur.

Type de données renvoyées

INTEGER

Remarques

Si la valeur est $Unknown au cours d'un téléchargement vers l'amont, la zone n'est pas prise en compte.

Exemple

TYPES
   SomeRec IS RECORD 
      first:STRING; 
      last :STRING; 
      age :INTEGER; 
      bday :DATE; 
END; 
VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
   rec :SomeRec; 
    ACTIONS 
   rc := EMUConnect(conn, 'A'); 
            IF (rc < 1) THEN 
    -- erreur de traitement
   ELSE 
      rec.first := 'Jean';
      rec.last := 'Mercier';
      rec.age := 30; 
      rec.bday := {8/6/1963}:DATE; 
      rc := EMUMapUpload(conn, 'EX1.MAP', rec); 
            IF (rc < 1) THEN 
    -- erreur de traitement 
END; 
      EMUDisconnect(conn);
END; 
END; 

Supposons que le contenu du fichier EX1.MAP est :

*FIELDS 
FIRST 3 14 10 SYSFORMAT DEFAULT_FORMAT 
LAST 4 12 20 SYSFORMAT DEFAULT_FORMAT 
AGE 5 6 3 SYSFORMAT DEFAULT_FORMAT 
BDAY 6 13 10 SYSFORMAT DEFAULT_FORMAT 

Supposons que l'écran d'hôte est semblable à :

========================================
PRENOM : __________
NOM : ____________________
AGE : ___
DATE DE NAISSANCE : __________


========================================

Losque l'exécution de EMUMapUpload a abouti, l'aspect de l'écran hôte est le suivant :

========================================
PRENOM : Jean
NOM : Mercier
AGE : 30
DATE DE NAISSANCE : 08/06/1963


========================================

Voir aussi :

EMUMoveCursorTo

Description

Déplace le curseur hôte vers la ligne et la colonne sélectionnées.

Paramètres

conn : EMUCONNECTION 
row : INTEGER EXPRESSION
col : INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Identifie la session de terminal vers laquelle le curseur doit être déplacé.
row Ligne de l'écran hôte vers laquelle le curseur doit être déplacé. La ligne située en haut de l'écran correspond à la première ligne.
col Colonne vers laquelle le curseur doit être déplacé. La colonne 1 correspond à celle qui est à l'extrême gauche de l'écran hôte.

Type de données renvoyées

INTEGER

Remarques

Vous ne pouvez pas déplacer le curseur lorsque l'hôte signale une entrée système verrouillée. Lorsqu'une ligne ou une colonne est située en dehors de la plage admise, un code d'erreur est renvoyé.

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
    ACTIONS 
   rc := EMUConnect(conn, 'A'); 
            IF (rc < 1) THEN 
    -- erreur de traitement
   ELSE 
      rc := EMUMoveCursorTo(conn, 10, 10); 
            IF (rc < 1) THEN 
    -- erreur de traitement 
   ELSE 
         EMUClrTypeIn(conn, 'THIS STARTS AT POSITION
                      10,10'); 
END; 
      EMUDisconnect(conn);
END; 
END; 

Voir aussi :

EMUQueryCursor

EMUOutFile

Description

Réalise le cliché d'une portion rectangulaire de l'écran hôte (définie par les coordonnées indiquées) destinée au fichier nommé.

Paramètres

conn : EMUCONNECTION 
filename: STRING EXPRESSION
topRow  : INTEGER EXPRESSION 
leftCol : INTEGER EXPRESSION 
botRow  : INTEGER EXPRESSION 
rightCol: INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Indique la session de terminal dans laquelle est réalisée la capture de la portion de texte.
filename Nom du fichier vers lequel le texte doit être cliché. Si le fichier existe déjà, les nouvelles données remplacent les anciennes. Lorsque ce fichier n'existait pas, il est créé.
topRow Ligne de l'hôte située en haut de la portion rectangulaire de texte.
leftCol Numéro de la colonne de terminal correspondant à la dernière colonne située à gauche du texte inscrit dans le fichier.
botRow Ligne de l'écran hôte située en bas de la portion rectangulaire de texte.
rightCol Colonne de l'écran hôte utilisée comme colonne d'extrême droite de la portion rectangulaire de texte.

Type de données renvoyées

INTEGER

Remarques

Si le fichier n'est pas au moment de l'exécution de la commande, il est créé. S'il existe déjà, les nouvelles données sont rattachées à la fin du fichier.

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
   msg :STRING; 
    ACTIONS 
   rc := EMUConnect(conn, 'A'); 
            IF (rc < 1) THEN 
    -- erreur de traitement
   ELSE 
      rc := EMUFillBuffer(conn, 3, 1, 5, msg); 
            IF (rc < 1) THEN 
    -- erreur de traitement 
   ELSE 
         IF (msg = 'ERROR') THEN 
            -- réalisez un fichier de capture d'écran
            EMUOutFile(conn, 'ERRFILE.TXT',1,1,24,80); 
END; 
END; 
      EMUDisconnect(conn);
END; 
END; 

Voir aussi :

EMUInFile

EMUPressKey

Description

Enfonce la touche de contrôle désignée par un code de touche. Les codes de touches peuvent correspondre à l'une des valeurs entières de TSD Script définies par le système ($EMUClearKey, $EMUEnter).

Paramètres

conn : EMUCONNECTION 
keycode: INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Identifie la session de terminal vers laquelle les saisies doivent être envoyées.
keycode Touche à enfoncer.

Type de données renvoyées

INTEGER

Remarques

Aucune saisie ne peut être effectuée lorsque l'hôte signale une entrée système verrouillée.

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
    ACTIONS 
   rc := EMUConnect(conn, 'A'); 
            IF (rc < 1) THEN 
    -- erreur de traitement
   ELSE 
      rc := EMUPressKey(conn, $EMUPF3); 
            IF (rc < 1) THEN 
    -- erreur de traitement 
   ELSE 
         EMUClrTypeIn(conn, 'JEAN_M');
   EMUPressKey(conn, $EMUTab); 
         EMUClrTypeIn(conn, 'mot de passe');
         rc := EMUPressKey(conn, $EMUEnter); 
            IF (rc < 1) THEN 
            -- erreur de traitement, la connexion a échoué.
END; 
END; 
END; 
END; 

EMUQueryCursor

Description

Permet de connaîte l'emplacement du curseur hôte.

Paramètres

conn : EMUCONNECTION 
row : INTEGER PARAMETER 
col : INTEGER PARAMETER 

Remarques concernant les paramètres

Paramètre Description
conn Indique la session de terminal à partir de laquelle la position du curseur est obtenue.
row Ligne sur laquelle le curseur est placé au moment de l'exécution de cette commande.
col Colonne dans laquelle le curseur hôte est positionné.

Type de données renvoyées

INTEGER

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
   r,c:INTEGER; 
    ACTIONS 
   ... 
   EMUPressKey(conn,$EMUEndKey); 
   EMUQueryCursor(conn,r,c); 
   IF (c > 59) THEN 
   EMUPressKey(conn, $EMUTab); 
END; 
   EMUTypeIn(conn,'Is this on new field?'); 
END; 

Voir aussi :

EMUMoveCursorTo

EMUQuerySession

Description

Renvoie la taille de l'écran en lignes et colonnes de texte.

Paramètres

conn : EMUCONNECTION 
row : INTEGER PARAMETER 
col : INTEGER PARAMETER 

Remarques concernant les paramètres

Paramètre Description
conn Indique la session de terminal pour laquelle la taille est obtenue.
row Ce paramètre permet de définir la hauteur de l'écran hôte.
col Contient le nombre de colonnes affichées dans l'écran hôte.

Type de données renvoyées

INTEGER

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
   r,c:INTEGER; 
    ACTIONS 
   ... -- à cet endroit du code, vous décidez de
       -- sauvegarder la capture d'écran hôte
       -- dans un fichier.
   EMUQuerySession(conn, r, c); 
   EMUOutFile(conn,'ERRFILE.TXT',1,1,r,c); 
END; 

EMUScanForString

Description

Lance un scannage de la session de terminal afin de rechercher la chaîne de caractères spécifiée. Si cette dernière a été trouvée, la fonction renvoie le point d'origine de la chaîne, au format ligne/colonne.

Paramètres

conn : EMUCONNECTION 
row : INTEGER PARAMETER 
col : INTEGER PARAMETER 

Remarques concernant les paramètres

Paramètre Description
conn Session de terminal à scanner
row Lorsque la chaîne a été trouvée, ce paramètre contient la ligne du début de la chaîne
col Colonne dans laquelle débute la chaîne de caractères trouvée

Type de données renvoyées

INTEGER

Remarques

Le transfert d'une chaîne de caractères vide ou $Unknown à EMUScanForString n'est pas une fonction admise. De plus, le scannage respecte les majuscules et les minuscules.

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
   r,c:INTEGER; 
    ACTIONS 
   ... 
   rc := EMUScanForString(conn,'JEAN MERCIER',r,c);
            IF (rc < 1) THEN 
      IF (rc = -24) THEN 
         WinMessageBox($DESKTOP,'Introuvable',$MBOK,
                       'Impossible de trouver '&
                       'JEAN MERCIER');
   ELSE 
         -- une autre erreur s'est produite
END; 
   ELSE 
      WinMessageBox($DESKTOP,'Trouvé',$MBOK,'Trouvé '&
                    'JEAN MERCIER à la ligne '& r &' colonne
                    '& c); 
END; 
END; 

EMUSetWatchTimeLimit

Description

Définit le délai d'attente de toutes les commandes Wait qui suivent cet appel.

Paramètres

conn : EMUCONNECTION 
timelimit: INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Session de terminal pour laquelle le délai d'attente limite est défini.
timelimit Durée d'attente maximale (en millisecondes) de toutes les commandes EMUWait avant leur annulation.

Type de données renvoyées

INTEGER

Remarques

La durée limite par défaut est de 500 millisecondes. La durée limite définie avec le paramètre EMUSetWatchTimeLimit est valable pour toutes les commandes EMUWait ultérieures (pour la connexion concernée). Une durée limite égale à 0 est admise. Dans ce cas, les fonctions EMUWait sont immédiatement renvoyées, avec des codes retour précisant si la condition a été satisfaite ou non.

Exemple

VARIABLES
            rc :INTEGER; 
   conn:EMUCONNECTOIN; 
    ACTIONS 
   .. 
   rc := EMUSetWatchTimeLimit(conn,1000); -- 1 seconde
            IF (rc < 1) THEN 
    -- erreur de traitement
   ELSE 
   rc := EMUWaitForNoX(conn); 
END; 
END; 

Voir aussi :

EMUTypeIn

Description

Saisit la chaîne de caractères à partir du point de positionnement du curseur.

Paramètres

conn : EMUCONNECTION 
str : STRING EXPRESSION 
length: INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Session de terminal dans laquelle la chaîne de caractères doit être saisie.
str Chaîne de caractères qui est saisie depuis le point de positionnement du curseur.
length (paramètre facultatif) Définit la longueur maximale de la chaîne à entrer. Celle-ci est tronquée lorsque sa longueur est supérieure à la limite autorisée.

Type de données renvoyées

INTEGER

Remarques

Lorsque la chaîne de caractères à entrer est vide, le code retour est 5008. Dans ce cas, aucun caractère n'est saisi dans l'écran hôte.

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
    ACTIONS 
   ... 
   EMUMoveCursorTo(conn, 10,10); 
   EMUTypeIn(conn,'JEAN MERCIER',20);
   EMUPressKey(conn,$EMUTab); 
   EMUTypeIn(conn,'18'); 
   EMUPressKey(conn,$EMUTab); 
   EMUTypeIn(conn,'19, rue du Lac',30);
   rc := EMUPressKey(conn,$EMUEnter); 
            IF (rc < 1) THEN 
    -- erreur de traitement
END; 
END; 

Voir aussi :

EMUWaitForCursorAt

Description

Suspend temporairement l'application jusqu'à ce que le curseur hôte s'affiche à l'emplacement désigné, ou jusqu'à l'expiration du temps limite de surveillance.

Paramètres

conn : EMUCONNECTION 
row : INTEGER EXPRESSION
col : INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Indique la session de terminal en attente.
row Emplacement de la ligne où le curseur est censé apparaître.
col Emplacement de la colonne où le curseur est censé apparaître.

Type de données renvoyées

INTEGER

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
    ACTIONS 
   ... 
   EMUPressKey(conn, $EMUPF3); 
   rc := EMUWaitForCursorAt(conn, 1, 5); 
            IF (rc < 1) THEN 
      IF ((rc = 1010) or (rc = 1011)) THEN 
         -- abandon du processus d'attente
   ELSE 
         -- erreur
END; 
   ELSE 
      -- poursuite normale du traitement 
END; 
END; 

Voir aussi :

EMUSetWatchTimeLimit

EMUWaitForCursorNotAt

Description

Suspend l'exécution jusqu'à ce que le curseur hôte soit positionné ailleurs qu'à l'emplacement spécifié, ou jusqu'à expiration de la durée limite de surveillance.

Paramètres

conn : EMUCONNECTION 
row : INTEGER EXPRESSION
col : INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Indique la connexion au terminal en attente.
row Ligne de laquelle le curseur doit disparaître.
col Colonne de laquelle le curseur doit disparaître.

Type de données renvoyées

INTEGER

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
    ACTIONS
   ... 
   EMUPressKey(conn, $EMUPF3); 
   rc := EMUWaitForCursorNotAt(conn, 10,10); 
            IF (rc < 1) THEN 
      IF (rc = 1010) THEN 
         -- abandon du processus d'attente
   ELSE 
         -- autre erreur
END; 
   ELSE 
      -- poursuite normale du traitement 
END; 
END; 

Voir aussi :

EMUSetWatchTimeLimit

EMUWaitForNoX

Description

Suspend l'exécution jusqu'à ce que l'indicateur de verrouillage d'entrée système n'apparaisse plus dans la zone d'informations utilisateur. Si une valeur est définie pour le temps d'établissement, l'interpréteur de TSD Script garantit que l'indicateur disparaîtra pendant toute la durée d'établissement, puis réapparaîtra.

Paramètres

conn : EMUCONNECTION 
settleTime: INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Spécifie la connexion au terminal en attente.
settleTime Paramètre facultatif. Durée pendant laquelle l'interpréteur de TSD Script attend la disparition de l'indicateur X, afin d'assurer que celui-ci est "établi".

Type de données renvoyées

INTEGER

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
    ACTIONS 
   ... 
   -- complétez l'écran à l'aide des données
   EMUMoveCursorTo(conn, 10, 10); 
   EMUClrTypeIn(conn, 'JEAN MERCIER');
   EMUPressKey(conn, $EMUTab); 
   EMUClrTypeIn(conn, '19, rue du Lac');
   EMUPressKey(conn, $EMUTab); 
   EMUClrTypeIn(conn, 'Ville, Pays');
   -- pour valider les données, appuyez sur la touche Entrée
EMUPressKey(conn, $EMUEnter); 
   rc := EMUWaitForNoX(conn); 
            IF (rc < 1) THEN 
      IF ((rc = 1011) OR (rc = 1012)) THEN 
         -- abandon du processus d'attente
   ELSE 
         -- autre erreur
END; 
   ELSE 
      -- poursuite normale du traitement
END; 
END; 

EMUWaitForStringAt

Description

Suspend l'exécution jusqu'à ce que la chaîne à rechercher soit affichée, son caractère initial étant placé sur la ligne et dans la colonne concernées, ou jusqu'à l'expiration de la durée limite de surveillance.

Paramètres

conn : EMUCONNECTION 
str : STRING EXPRESSION
row : INTEGER EXPRESSION
col : INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Indique la connexion au terminal en attente.
str Chaîne de caractères à attendre.
row Ligne de l'hôte dans laquelle s'affiche la chaîne de caractères.
col Colonne dans laquelle s'affiche la chaîne de caractères.

Type de données renvoyées

INTEGER

Remarques

Lorsque la chaîne de caractères est vide ou $Unknown, un code retour d'erreur est immédiatement renvoyé.

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
    ACTIONS 
   ... 
   EMUPressKey(conn, $EMUPF3); 
   rc := EMUWaitForStringAt(conn,'VEUILLEZ INDIQUER VOTRE NOM DE CONNEXION :', 3, 5); 
               IF (rc < 1) THEN 
      IF (rc = 1010) THEN 
         -- abandon du processus d'attente
   ELSE 
         -- autre erreur générale
END; 
   ELSE 
      -- poursuite normale du traitement
END; 
END; 

Voir aussi :

EMUSetWatchTimeLimit

EMUWaitForStringNotAt

Description

Suspend temporairement l'application jusqu'à ce que la chaîne de caractères disparaisse de l'emplacement désigné de l'hôte, ou jusqu'à l'expiration du temps limite de surveillance.

Paramètres

conn : EMUCONNECTION 
str : STRING EXPRESSION
row : INTEGER EXPRESSION
col : INTEGER EXPRESSION 

Remarques concernant les paramètres

Paramètre Description
conn Indique la connexion au terminal en attente.
str Chaîne de caractères disparaissant de l'écran hôte.
row Ligne de laquelle le curseur disparaît.
col Colonne de laquelle disparaît le caractère initial de la chaîne de caractères.

Type de données renvoyées

INTEGER

Remarques

Lorsque la chaîne de caractères est vide ou $Unknown, un code retour d'erreur s'affiche.

Exemple

VARIABLES
            rc :INTEGER; 
conn:EMUCONNECTION; 
    ACTIONS 
   ... 
   EMUMoveCursorTo(conn, 10, 10); 
   EMUClrTypeIn(conn,'JEAN MERCIER');
EMUPressKey(conn, $EMUEnter); 
   rc := EMUWaitForStringNotAt(conn, 'JEAN MERCIER', 10, 10);
            IF (rc < 1) THEN 
      IF (rc = 1010) THEN 
         -- abandon du processus d'attente
   ELSE 
         -- autre erreur générale
END; 
   ELSE 
      -- poursuite normale du traitement
END; 
END; 

Voir aussi :

EMUSetWatchTimeLimit


Tivoli Service Desk 6.0 Developer's Toolkit - Guide des API existantes

Retour à la table des matières

Copyright